Ein Haushaltsbuch in Excel ist eine Liste dessen, was reinkommt und was rausgeht, mit einer Handvoll Formeln, die den Rest ausrechnen. Du brauchst kein spezielles Programm und keine App. Ein Blatt mit dem Einkommen oben, den Ausgaben darunter und einer Summe ganz unten sagt dir, wie viel Geld jeden Monat übrig bleibt und wo der Rest hingeht.
Hier bekommst du eine kostenlose Haushaltsbuch-Vorlage für Excel mit vier Blättern: das Budget selbst, deine Ausgaben pro Kategorie, ein laufender Kontostand und deine Sparziele. Danach geht die Anleitung jede Formel der Vorlage durch, damit du sie anpassen oder dein eigenes Haushaltsbuch von Grund auf bauen kannst. Zu jeder Formel gehört ein Beispiel, das du Zelle für Zelle lesen kannst, und eine Übung, in der du sie selbst schreibst. Alle Übungen liegen auch gesammelt in den Übungen zum Haushaltsbuch.
Kostenlos mit Konto
Haushaltsbuch-Vorlage für Excel
Ein fertiges Haushaltsbuch in Excel: Fixkosten, jährliche und vierteljährliche Rechnungen, Ausgaben pro Kategorie, ein laufender Kontostand und Sparziele.
Was in der Datei steckt
- Budget: Einkommen und Ausgaben pro Monat und pro Jahr. Vierteljährliche, halbjährliche und jährliche Rechnungen werden auf einen Betrag pro Monat umgerechnet.
- Ausgaben: Deine Einkäufe mit Datum und Kategorie. SUMMEWENN zeigt, wie viel vom Budget jeder Kategorie übrig ist.
- Kontostand: Geld rein und raus mit einem laufenden Kontostand: der Kontostand darüber plus Eingang minus Ausgang.
- Sparziele: Deine Sparziele, was noch fehlt und wie viele Monate es noch dauert, aufgerundet mit AUFRUNDEN.
Excel-Datei (.xlsx). Lässt sich auch in Google Sheets öffnen. Das Konto ist kostenlos und speichert auch deinen Fortschritt in den Übungen.
So ist die Vorlage aufgebaut
Die Vorlage öffnet auf dem Blatt Hier starten mit einer kurzen Erklärung der anderen Blätter. Auf allen Blättern gilt dasselbe: Du tippst in die hellen Felder, und die Zellen mit Formeln rechnen selbst. Die Überschriften stehen in der ersten Zeile und bleiben stehen, wenn du nach unten scrollst.
- Budget ist das monatliche Budget. Du trägst jeden Posten ein, den Betrag und wie oft er bezahlt wird. Das Blatt rechnet ihn auf einen Betrag pro Monat und pro Jahr um, zeigt, welchen Anteil am Einkommen jeder Posten hat, und ganz unten steht, was übrig bleibt.
- Ausgaben sind deine Einkäufe im Lauf des Monats. Jeder Einkauf bekommt eine Kategorie aus einer Dropdown-Liste, und eine kleine Tabelle daneben zeigt, wie viel du in jeder Kategorie ausgegeben hast und wie viel vom Budget übrig ist.
- Kontostand ist Geld rein und Geld raus mit einem Kontostand, der von Zeile zu Zeile mitläuft, wie auf einem Kontoauszug.
- Sparziele sind deine Ziele, etwa ein Urlaub oder ein Notgroschen, mit dem, was noch fehlt, und wie viele Monate es dauert, bis du das Ziel erreichst.
Die Blätter sind nicht über Formeln verbunden. Du kannst sie einzeln nutzen und die löschen, die du nicht brauchst, ohne dass etwas anderes kaputtgeht.
Was übrig bleibt: das frei verfügbare Geld
Die wichtigste Zahl in einem Haushaltsbuch ist das, was übrig bleibt, wenn alles bezahlt ist. Viele nennen es das frei verfügbare Einkommen. In Excel ist es das Einkommen minus die Summe der Ausgaben:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Posten | Pro Monat | ||
| 2 | Nettoeinkommen | 5200 | 2500 | |
| 3 | Miete | 1100 | ||
| 4 | Strom und Heizung | 150 | ||
| 5 | Mobilität | 250 | ||
| 6 | Lebensmittel | 650 | ||
| 7 | Abos | 50 | ||
| 8 | Sparen | 500 |
Das Einkommen steht oben und die Ausgaben darunter. 5.200 € minus 2.700 € Ausgaben ergeben 2.500 €, die jeden Monat übrig bleiben.
=B2-SUMME(B3:B8) besteht aus zwei Teilen. SUMME addiert alle Ausgaben in B3 bis B8, und das Minus zieht die Summe vom Einkommen in B2 ab. Du könntest auch =B2-B3-B4-B5-B6-B7-B8 schreiben, aber diese Formel musst du jedes Mal ändern, wenn du eine Ausgabe hinzufügst. SUMME über einen Bereich nimmt alle Zeilen mit, auch die, die du später mitten im Bereich einfügst.
In der Vorlage liegt die Summe in einer eigenen Zeile, Ausgaben gesamt, mit =SUMME(D3:D17). Der Bereich reicht drei Zeilen weiter nach unten als die letzte Ausgabe, deshalb ist Platz für neue Posten, ohne dass die Formel geändert werden muss. Leere Zellen zählen in einer SUMME als 0, die zusätzlichen Zeilen schaden also nicht. Die Zeile darunter, Übrig pro Monat, ist =D2-D18, also das Einkommen minus die Summe.
Wird die Zahl negativ, gibst du mehr Geld aus, als du verdienst. Das ist kein Fehler im Blatt, sondern ein Zeichen, dass eine Ausgabe runter muss oder das Sparen einen Monat warten muss.
Beachte, dass das Sparen im Budget als Ausgabe steht. Das ist eine Entscheidung: Wenn du zuerst sparst, ist das, was übrig bleibt, das Geld, das du frei ausgeben kannst. Willst du lieber sehen, wie viel du sparen kannst, nimm das Sparen aus den Ausgaben heraus und lies das Ergebnis als den Betrag, den du zurücklegen kannst.
Probier die Formel selbst in der Übung Das frei verfügbare Geld mit SUMME.
Fixe und variable Kosten
Bevor du Zahlen eintippst, hilft es, die Ausgaben in zwei Arten zu teilen. Fixkosten kosten jedes Mal dasselbe: Miete, Versicherungen, Internet, Mitgliedsbeiträge, Abos und Kreditraten. Variable Kosten ändern sich von Monat zu Monat: Lebensmittel, Mobilität, Kleidung, Geschenke und Freizeit.
Die Fixkosten sind leicht zu planen, weil du sie auf den Rechnungen oder im Onlinebanking ablesen kannst. Die variablen sind schwieriger. Hier ist der beste Schätzwert ein Durchschnitt der letzten drei Monate. Nutze das Blatt Ausgaben ein oder zwei Monate lang, dann hast du die echten Zahlen statt einer Schätzung.
Trag die Beträge netto ein, also nach Steuern und Abgaben, und schreib die Rechnungen so, wie sie auf dem Papier stehen. Zahlst du das Wasser vierteljährlich, schreib den Quartalsbetrag und wähle Vierteljährlich. Der nächste Abschnitt zeigt, wie die Vorlage daraus einen Betrag pro Monat macht.
Bekommst du Weihnachtsgeld oder ein 13. Gehalt, ist ein Monat nicht einfach ein Gehalt. Verteil das Jahr auf zwölf Monate: Mit einem Monatsgehalt in B2 und einem 13. Gehalt ist dein Einkommen pro Monat =B2*13/12. Trag den monatlichen Wert in die Zeile mit dem Einkommen ein.
Rechnungen, die nicht jeden Monat kommen
Manche Rechnungen kommen einmal im Jahr oder jedes Quartal: Hausratversicherung, Kfz-Versicherung, Wasser, Grundsteuer und Rundfunkbeitrag. Vergisst du sie im Haushaltsbuch, sieht jeder Monat gut aus, bis zu dem Monat, in dem die Rechnung kommt. Die Lösung ist, jede Rechnung auf die Monate zu verteilen, die sie abdeckt. Dann zeigt das Budget, was sie pro Monat kostet.
In der Vorlage trägst du den Betrag in Betrag ein und wählst in Zahlweise, wie oft er bezahlt wird. Die Spalte Pro Monat rechnet den Rest mit WENN (IF) aus:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Posten | Betrag | Zahlweise | Pro Monat |
| 2 | Kfz-Versicherung | 1800 | Jährlich | 150 |
| 3 | Wasser | 180 | Vierteljährlich | |
| 4 | Miete | 1100 | Monatlich |
Die Kfz-Versicherung kostet 1.800 € im Jahr. Auf 12 Monate verteilt sind das 150 €, und dieser Betrag gehört ins Haushaltsbuch.
Die Formel liest sich von innen nach außen. Steht Jährlich in C2, ist die Antwort B2 geteilt durch 12. Sonst fragt das innere WENN, ob Vierteljährlich dort steht, und dann ist die Antwort B2 geteilt durch 3. Steht etwas anderes dort, ist der Betrag schon ein Monatsbetrag, und die Antwort ist B2, wie es ist. Die Vorlage hat außerdem die Option Halbjährlich. Die teilt durch 6, die vollständige Formel hat also drei WENN ineinander:
=WENN(C2="Jährlich";B2/12;WENN(C2="Halbjährlich";B2/6;WENN(C2="Vierteljährlich";B2/3;B2)))
Hast du Excel 2019 oder neuer, kannst du dasselbe mit WENNS (IFS) schreiben. Es nimmt die Bedingungen nacheinander, ohne sie ineinander zu verpacken, und WAHR am Ende fängt alles andere ab:
=WENNS(C2="Jährlich";B2/12;C2="Halbjährlich";B2/6;C2="Vierteljährlich";B2/3;WAHR;B2)
Die Spalte Pro Jahr ist einfach =D2*12. Sie ist nützlich, wenn du sehen willst, was eine kleine Ausgabe über ein ganzes Jahr kostet. 30 € im Monat für Streaming sind 360 € im Jahr.
Hast du ein eigenes Konto für die festen Rechnungen, ist die Summe von Pro Monat für die Fixkosten der Betrag, den du jeden Monat auf dieses Konto überweisen solltest. Dann ist genug Geld da, auch in den Monaten, in denen die großen Rechnungen kommen.
Übe die Formel in Jährliche und vierteljährliche Rechnungen pro Monat und lies mehr über Bedingungen in der Anleitung zur WENN-Funktion.
Warum die Zahlweise eine Dropdown-Liste ist
WENN vergleicht den Text in C2 mit dem Text in der Formel. Steht dort jährl. oder Pro Jahr, ist das nicht dasselbe wie Jährlich, und die Formel fällt bis zur letzten Antwort durch und behandelt die Jahresrechnung wie eine monatliche. Groß- und Kleinschreibung spielt keine Rolle, jährlich funktioniert also, aber jede andere Schreibweise ergibt eine falsche Zahl ohne jede Fehlermeldung.
Deshalb ist die Spalte eine Dropdown-Liste mit den vier Einträgen, die die Formel kennt. Du kannst nichts anderes eintippen, und eine falsche Zahl kann sich nicht einschleichen. In der Anleitung zu Dropdown-Listen in Excel siehst du, wie du selbst eine erstellst und die Einträge änderst.
Welchen Anteil am Einkommen hat jeder Posten?
Ein Betrag sagt am meisten, wenn du ihn im Verhältnis zum Einkommen siehst. 1.050 € Miete sind viel oder wenig, je nachdem, was du verdienst. Die Spalte Anteil am Einkommen teilt jeden Posten durch das Einkommen:
| A | B | C | |
|---|---|---|---|
| 1 | Posten | Pro Monat | Anteil am Einkommen |
| 2 | Nettoeinkommen | 3000 | |
| 3 | Miete | 1050 | 0,35 |
| 4 | Lebensmittel | 450 |
Eine Miete von 1.050 € sind 35 % eines Einkommens von 3.000 €. Die Dollarzeichen halten das Einkommen fest, wenn die Formel nach unten kopiert wird.
Das Ergebnis ist 0,35, und im Prozentformat wird es als 35 % angezeigt. Wichtig sind die Dollarzeichen in $B$2. Wenn du die Formel nach unten kopierst, soll der Zähler zum nächsten Posten wandern, der Nenner aber beim Einkommen bleiben. Ohne $ würde die Zeile darunter durch B3 teilen und so weiter, und die Zahlen wären falsch. Mehr über fixierte Zellbezüge liest du in Zellen sperren in Excel.
Die Anteile machen es leicht zu sehen, wohin das Geld geht. Eine Faustregel, die viele nutzen, ist, dass das Wohnen nicht viel mehr als ein Drittel des Einkommens kosten sollte. Am nützlichsten ist aber der Vergleich mit dir selbst: Steigt der Anteil für Lebensmittel in einem halben Jahr von 18 % auf 24 %, weißt du, wo du hinschauen musst. Mehr zum Rechnen mit Prozenten findest du in Prozentrechnung in Excel.
Ausgaben pro Kategorie mit SUMMEWENN
Das Budget sagt, was du ausgeben willst. Das Blatt Ausgaben zeigt, was du tatsächlich ausgegeben hast. Du trägst jeden Einkauf in eine Zeile mit Datum, Text, Kategorie und Betrag ein, und eine kleine Tabelle daneben addiert die Beträge pro Kategorie mit SUMMEWENN (SUMIF):
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Einkauf | Kategorie | Betrag | Kategorie | Ausgegeben | |
| 2 | Supermarkt | Lebensmittel | 312 | Lebensmittel | 760 | |
| 3 | Deutschlandticket | Mobilität | 58 | Mobilität | ||
| 4 | Wochenmarkt | Lebensmittel | 85 | |||
| 5 | Kino | Freizeit | 26 | |||
| 6 | Supermarkt | Lebensmittel | 363 | |||
| 7 | Tanken | Mobilität | 70 |
SUMMEWENN addiert nur die Einkäufe mit der Kategorie in E2. Drei Einkäufe für Lebensmittel ergeben 312 + 85 + 363 = 760 €.
SUMMEWENN nimmt drei Argumente: wo es nach der Kategorie suchen soll, welche Kategorie es finden soll und was es addieren soll. =SUMMEWENN($B$2:$B$7;E2;$C$2:$C$7) sucht in den Kategorien in B2:B7, findet die Zeilen, in denen dasselbe steht wie in E2, und addiert die zugehörigen Beträge in C2:C7.
Die Kategorie steht in einer Zelle, statt in die Formel getippt zu sein. So kannst du die Formel zu den anderen Kategorien nach unten kopieren, und aus E2 wird E3, E4 und so weiter. Die beiden Bereiche sind mit $ fixiert, sie bleiben also stehen. In der Vorlage reichen die Bereiche bis Zeile 51, das gibt Platz für 50 Einkäufe im Monat: =SUMMEWENN($C$2:$C$51;F2;$D$2:$D$51).
Die Dropdown-Liste in der Spalte Kategorie holt ihre Einträge aus der Kategorietabelle in F2:F6. Änderst du dort eine Kategorie oder schreibst du eine neue in eine leere Zeile innerhalb des Bereichs, kommt sie in die Liste, und SUMMEWENN findet sie. Brauchst du mehr Kategorien, als die Tabelle Platz hat, füg eine neue Zeile mitten in der Tabelle ein. Dann wachsen Liste und Summe mit.
Übe SUMMEWENN in Ausgaben pro Kategorie mit SUMMEWENN und in SUMMEWENN mit dem Kriterium in einer Zelle. Die Funktion wird Argument für Argument auf der Seite zu SUMMEWENN erklärt.
Budget und Ausgaben im Vergleich
Neben Ausgegeben stehen Budget und Übrig. Übrig ist einfach das Budget minus das Ausgegebene, =G2-H2. Eine negative Zahl heißt, dass du in dieser Kategorie mehr ausgegeben hast als geplant.
Willst du das sofort sehen, gib der Spalte eine bedingte Formatierung, die die Zelle rot färbt, wenn die Zahl unter 0 liegt. Dann leuchten die Kategorien auf, in denen du über dem Budget liegst, ohne dass du jede Zahl lesen musst. Wie das geht, steht in der Anleitung zur bedingten Formatierung.
Ein laufender Kontostand
Das Blatt Kontostand sieht aus wie ein Kontoauszug: Datum, Text, Eingang, Ausgang und ein Kontostand nach jeder Zeile. Die erste Zeile enthält deinen Anfangssaldo, den trägst du selbst ein. Jede Zeile darunter rechnet ihren Kontostand aus der Zeile darüber aus:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Text | Eingang | Ausgang | Kontostand |
| 2 | Anfangssaldo | 5000 | ||
| 3 | Fahrradreparatur | 750 | 4250 | |
| 4 | Gehalt | 2800 |
Der Kontostand ist der Kontostand in der Zeile darüber plus Eingang minus Ausgang. 5.000 € minus eine Reparatur für 750 € ergeben 4.250 €.
=D2+B3-C3 nimmt den Kontostand der Zeile darüber, addiert den Eingang und zieht den Ausgang ab. Jede Zeile hat entweder einen Eingang oder einen Ausgang. Die leere Zelle zählt als 0, die Formel funktioniert also in beiden Fällen. Kopierst du die Formel nach unten, zeigt jede Zeile auf den Kontostand direkt über ihr, und der Kontostand läuft den ganzen Weg mit.
Die Formel darf keine Dollarzeichen haben. Sie muss jedes Mal eine Zeile mitwandern, sonst rechnen alle Zeilen vom Anfangssaldo aus. Das ist das Gegenteil vom Anteil am Einkommen. Dort sollte der Nenner fest stehen.
Der Kontostand in der letzten Zeile muss zum Kontostand im Onlinebanking passen. Tut er das nicht, fehlt eine Buchung, oder ein Betrag steht in der falschen Spalte. Diese Kontrolle ist eine gute Gewohnheit, und es ist dieselbe Art Abstimmung, die eine Buchhalterin jeden Monat macht. Probier die Formel in Ein laufender Kontostand.
Sparziele: wie viele Monate noch?
Das Blatt Sparziele hat eine Zeile für jedes Ziel mit dem Preis, dem, was du bisher gespart hast, und dem, was du jeden Monat zurücklegst. Zwei Formeln rechnen den Rest aus.
Fehlt noch ist der Preis minus das Gesparte, =MAX(0;B2-C2). MAX wählt die größere der beiden Zahlen, wenn du also mehr gespart hast als das Ziel, zeigt die Zelle 0 statt eines negativen Betrags.
Monate übrig teilt, was noch fehlt, durch das, was du jeden Monat sparst, und rundet auf:
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Ziel | Preis | Gespart | Pro Monat | |
| 2 | Urlaub | 3000 | 900 | 300 | |
| 3 | Neuer Laptop | 1200 | 150 | 100 | 11 |
Für den Laptop fehlen noch 1.050 €. Mit 100 € im Monat sind das 10,5 Monate, und AUFRUNDEN macht daraus 11, denn im 11. Monat erreichst du das Ziel.
1.050 geteilt durch 100 sind 10,5. Nach 10 Monaten fehlt dir noch etwas, also muss die Antwort auf 11 aufgerundet werden. AUFRUNDEN (ROUNDUP) rundet immer weg von null, und 0 als zweites Argument heißt keine Nachkommastellen. RUNDEN (ROUND) ergäbe hier zwar auch 11, aber 10,2 Monate würden zu 10, und dann fehlte dir im letzten Monat Geld.
Die Vorlage verpackt die Formel in WENN, =WENN(D2>0;AUFRUNDEN(E2/D2;0);""). Steht 0 oder nichts in Pro Monat, ergäbe die Division den Fehler #DIV/0!. WENN zeigt stattdessen eine leere Zelle, bis du einen Betrag eingetragen hast.
Übe die Formel in Monate bis zum Sparziel mit AUFRUNDEN und sieh dir weitere Beispiele auf der Seite zu AUFRUNDEN an.
Bau dein eigenes Haushaltsbuch von Grund auf
Die Vorlage ist ein guter Startpunkt, aber ein Haushaltsbuch, das du selbst gebaut hast, verstehst du besser, und es lässt sich leichter anpassen. So baust du ein einfaches Haushaltsbuch auf einem leeren Blatt:
- Schreib die Überschriften in Zeile 1: Posten, Betrag, Zahlweise und Pro Monat.
- Schreib dein Nettoeinkommen in Zeile 2. Hast du mehrere Einkommen, gib jedem eine eigene Zeile und addiere sie in einer eigenen Zeile.
- Schreib deine Ausgaben in die Zeilen darunter, einen Posten pro Zeile, mit dem Betrag, wie er auf der Rechnung steht.
- Wähle in Zahlweise, wie oft jede Rechnung kommt, und schreib die WENN-Formel von oben in Pro Monat. Kopier sie mit Strg+U nach unten.
- Addiere die Ausgaben mit SUMME in einer Zeile unter der letzten Ausgabe und lass den Bereich ein paar Zeilen weiter nach unten reichen.
- Zieh die Summe in der Zeile darunter vom Einkommen ab. Das ist dein frei verfügbares Geld.
- Formatiere die Beträge als Währung und fixiere die oberste Zeile, damit die Überschriften beim Scrollen stehen bleiben.
Danach kannst du Zahlweise zu einer Dropdown-Liste machen und eine Spalte mit dem Anteil am Einkommen hinzufügen. Dann hast du dasselbe wie das erste Blatt der Vorlage, und du weißt, wie jede Zelle gebaut ist. Brauchst du unterwegs mehr Tastenkombinationen, schau in die Liste der Excel-Tastenkombinationen.
Ein Diagramm der Ausgaben
Ein Diagramm macht deutlich, wohin das Geld geht. Markier die Posten und die Spalte Pro Monat und füg ein Balkendiagramm ein. Sortier die Zeilen vorher nach Betrag, vom kleinsten zum größten. Ein Balkendiagramm zeichnet die erste Zeile ganz unten, so kommt die größte Ausgabe nach oben, und das Diagramm ist leicht zu lesen.
Ein Kreisdiagramm ist die klassische Wahl für ein Haushaltsbuch, aber mit mehr als fünf oder sechs Posten wird es schwer lesbar, weil das Auge Winkel schlecht vergleicht. Balken vergleichst du auf einen Blick. Wie du beide Arten erstellst und anpasst, steht in der Anleitung zu Diagrammen in Excel.
Typische Fehler im Haushaltsbuch
- Die großen Rechnungen fehlen. Versicherungen und andere Jahresrechnungen werden vergessen, weil sie nicht jeden Monat kommen. Geh im Onlinebanking ein Jahr zurück und schreib alle Rechnungen auf.
- Monats- und Jahresbeträge sind vermischt. Eine Jahresrechnung, die als Monatsbetrag eingetragen ist, macht diesen Posten zwölfmal zu teuer. Schreib den Betrag, wie er auf der Rechnung steht, und lass Zahlweise umrechnen.
- Die Summe nimmt die neuen Zeilen nicht mit. Schreibst du einen Posten unter die Summe oder außerhalb des Bereichs der SUMME, kommt er nicht mit. Füg neue Zeilen innerhalb des Bereichs ein.
- Zahlen, die als Text gespeichert sind. Ein Betrag, der aus dem Onlinebanking kopiert wurde, kann als Text gespeichert sein. Er steht linksbündig in der Zelle, und SUMME überspringt ihn. Tipp ihn neu oder sieh dir an, wie du das in der Anleitung zum Daten bereinigen behebst.
- Ein Tippfehler in der Zahlweise. jährl. statt Jährlich sorgt dafür, dass die Rechnung als monatlich gezählt wird. Nutze die Dropdown-Liste.
- Ein Nenner, der mitwandert. Fehlt das Dollarzeichen im Anteil am Einkommen, teilen die Zeilen darunter durch die falschen Zellen. Fixiere das Einkommen mit
$B$2. - Nur ein Budget und keine Ausgaben. Ein Budget, das nie mit den tatsächlichen Ausgaben verglichen wird, ist eine Schätzung. Trag einen Monat lang deine Einkäufe ein und pass das Budget danach an.
Haushaltsbuch in Google Sheets
Die Vorlage funktioniert auch in Google Sheets. Lade die Datei in Google Drive hoch und öffne sie mit Google Sheets. Die Formeln, die Dropdown-Listen und die Zahlenformate kommen mit. Willst du das Haushaltsbuch lieber in Sheets von Grund auf bauen, funktionieren alle Formeln dieser Anleitung auch dort. Die anderen Unterschiede findest du in Google Sheets oder Excel.
Budget im Unternehmen
Ein Haushaltsbuch und ein Budget im Unternehmen sind gleich aufgebaut: Posten in Zeilen, Perioden in Spalten, eine Summe und eine Abweichung zwischen Plan und Ist. Der Unterschied ist die Größe und woher die Daten kommen. Im Unternehmen werden die Ist-Kosten aus der Buchhaltungssoftware exportiert und mit SUMMEWENNS (SUMIFS) statt SUMMEWENN addiert, weil es sowohl ein Konto als auch eine Kostenstelle gibt, nach der sortiert wird. Mehr dazu liest du in Excel im Finanzbereich.
Kurz gesagt
Ein Haushaltsbuch in Excel ist das Einkommen minus die Summe der Ausgaben. Schreib jede Rechnung, wie sie kommt, und lass WENN die jährlichen und vierteljährlichen auf einen Monatsbetrag umrechnen, damit dich die großen Rechnungen nicht überraschen. Teile jeden Posten durch das Einkommen, um zu sehen, wohin das Geld geht, und fixiere das Einkommen mit $. Trag deine Einkäufe ein und addiere sie mit SUMMEWENN pro Kategorie, damit du Budget und Ausgaben nebeneinander siehst. Ein laufender Kontostand ist der Kontostand darüber plus Eingang minus Ausgang, und AUFRUNDEN sagt dir, wie viele Monate es bis zu einem Sparziel noch dauert.
Die Übungen unten trainieren jede Formel der Vorlage an einer kleinen Tabelle, vom frei verfügbaren Geld bis zum Sparziel. Probier die erste Übung kostenlos aus und schreib die Formel selbst.

Über den Autor
Nicolaj, Gründer von ExcelPraxis
Ich bin Softwareentwickler und habe ExcelPraxis von Grund auf gebaut, auch die Tabelle selbst und die Engine, die die Formeln berechnet. Damit das funktioniert, musste ich jede Funktion bis ins Detail verstehen: wie sich SVERWEIS verhält, wenn ein Code ein Leerzeichen zu viel hat, warum ein Datum eigentlich eine Zahl ist und wann RUNDEN ein anderes Ergebnis liefert als das Zahlenformat.
Üb, was diese Anleitung behandelt
Übungen mit Korrektur in einer echten Tabelle, in der Reihenfolge der Anleitung.
- Was nach den Fixkosten bleibt, mit SUMMEHaushaltsbuch und Budget →
- Jährliche und vierteljährliche Rechnungen pro MonatHaushaltsbuch und Budget →
- Ausgaben pro Kategorie mit SUMMEWENNHaushaltsbuch und Budget →
- Ein laufender KontostandHaushaltsbuch und Budget →
- Monate bis zum Sparziel mit AUFRUNDENHaushaltsbuch und Budget →
- SUMMEWENN mit der Bedingung in einer ZelleSUMMEWENN →
Funktionsseiten
Fragen
Wie erstelle ich ein Haushaltsbuch in Excel?
Schreib dein Nettoeinkommen oben und deine Ausgaben in die Zeilen darunter, einen Monatsbetrag pro Posten. Addiere die Ausgaben mit SUMME und zieh sie vom Einkommen ab. Das Ergebnis ist das Geld, das dir jeden Monat übrig bleibt.
Wie rechne ich eine Jahresrechnung auf einen Monatsbetrag um?
Teile sie durch 12. Eine vierteljährliche Rechnung teilst du durch 3 und eine halbjährliche durch 6. Steht in einer Spalte, wie oft die Rechnung kommt, kann WENN die richtige Zahl für dich wählen, =WENN(C2="Jährlich";B2/12;WENN(C2="Vierteljährlich";B2/3;B2)).
Was ist das frei verfügbare Einkommen?
Das ist das Geld, das übrig bleibt, wenn die festen Ausgaben bezahlt sind. In Excel ist es das Einkommen minus die Summe der Ausgaben, =B2-SUMME(B3:B8). Zählst du das Sparen als Ausgabe mit, ist der Rest das Geld, das du frei ausgeben kannst.
Wie sehe ich meine Ausgaben pro Kategorie in Excel?
Trag jeden Einkauf in eine Zeile mit einer Kategorie und einem Betrag ein. Nutze dann SUMMEWENN, um die Beträge jeder Kategorie zu addieren, =SUMMEWENN($B$2:$B$51;E2;$C$2:$C$51) mit der Kategorie in E2.
Ist die Haushaltsbuch-Vorlage kostenlos?
Ja. Du siehst die ganze Vorlage und alle Formeln hier auf der Seite. Die Datei selbst lädst du mit einem kostenlosen Konto bei ExcelPraxis herunter, das auch deinen Fortschritt in den Übungen speichert.
Funktioniert die Vorlage in Google Sheets?
Ja. Lade die Datei in Google Drive hoch und öffne sie in Google Sheets. Die Formeln, die Dropdown-Listen und die Formate kommen mit.
Weitere Anleitungen
- Prozentrechnung in Excel: Prozent, Mehrwertsteuer und Veränderung berechnenProzent von einem Wert, Aufschlag, Rabatt, Mehrwertsteuer drauf- und herausrechnen, prozentuale Veränderung und Handelsspanne in Excel, jeweils mit einer kurzen Formel.
- Dropdown-Liste in Excel: so erstellst du eine Liste, die sich selbst aktualisiertErstell eine Dropdown-Liste in Excel aus getippten Einträgen, einem Bereich oder einem anderen Blatt, halte sie aktuell, verknüpfe Listen und schreib eigene Regeln.
- Bedingte Formatierung in Excel: Zellen und ganze Zeilen mit Regeln und Formeln färbenSo funktioniert die bedingte Formatierung, die fertigen Regeln und die Formeln, die ganze Zeilen, überschrittene Fristen, Duplikate und mehr färben.
- Diagramme in Excel: Säulen-, Linien- und Kreisdiagramme erstellenErstell ein Diagramm in Excel in drei Schritten, wähl den richtigen Diagrammtyp für deine Daten und behebe die typischen Fehler. Mit den Formeln für die Tabelle dahinter.
- Excel im Finanzbereich: die Fähigkeiten, die du wirklich brauchstDie Excel-Fähigkeiten, die Buchhaltung und Controlling täglich nutzen, von SUMMEWENNS und Budgetabweichungen bis zu Rundung, Monatsabschluss, RMZ und Kontrollsummen.