Die Funktion WENN

Gibt einen Wert zurück, wenn eine Prüfung WAHR ist, und einen anderen, wenn sie FALSCH ist. Text im Ergebnis steht in Anführungszeichen.

Auf Englisch heißt die Funktion IF, und in den Übungen kannst du beide Namen schreiben. Alle Funktionsnamen auf Deutsch und Englisch

Syntax

WENN(Prüfung; [Dann_Wert]; [Sonst_Wert])
Prüfung
Ein Vergleich, der WAHR oder FALSCH ergibt, zum Beispiel A2>=50.
Dann_Wert (optional)
Das, was zurückgegeben wird, wenn die Prüfung WAHR ist.
Sonst_Wert (optional)
Das, was zurückgegeben wird, wenn die Prüfung FALSCH ist.

Beispiele

C1=WENN(A2>=50;"Bestanden";"Nicht bestanden")
ABC
1PunkteBestanden
262

In einfachen Worten: Wenn die Punktzahl in A2 50 oder mehr ist, dann zeig Bestanden. Sonst zeig Nicht bestanden.

C1=WENN(A2>100;A2*0,1;0)
ABC
1Punkte0
262
C1=WENN(ISTZAHL(SUCHEN("pro";A2));"Pro";"Standard")
ABC
1ProduktPro
2Laptop PRO 14

In einfachen Worten: Wenn der Produktname in A2 pro enthält, dann zeig Pro. Sonst zeig Standard.

WENN üben

Anleitung lesen

Fragen

Wie mache ich eine WENN-Funktion mit mehreren Bedingungen?

Nimm UND oder ODER als Prüfung, zum Beispiel =WENN(UND(A2>=50;B2="Ja");"Angenommen";"Abgelehnt"). Mit UND müssen alle Bedingungen erfüllt sein, mit ODER reicht eine.

Wie prüfe ich, ob eine Zelle einen bestimmten Text enthält?

WENN versteht keine Platzhalter, also kombinier es mit SUCHEN und ISTZAHL, =WENN(ISTZAHL(SUCHEN("pro";A2));"Pro";"Standard"). SUCHEN unterscheidet nicht zwischen Groß- und Kleinschreibung, FINDEN schon. Willst du nur wissen, ob in der Zelle Text steht, nimm =WENN(ISTTEXT(A2);"Text";"Kein Text").

Warum funktioniert meine WENN-Formel nicht?

Text in der Prüfung und in den Ergebnissen muss in Anführungszeichen stehen, zum Beispiel =WENN(A2="Bezahlt";"Fertig";"Offen"). Ohne sie zeigt Excel

Wie lasse ich die Zelle leer, wenn die Bedingung nicht erfüllt ist?

Nimm zwei Anführungszeichen als Ergebnis, zum Beispiel =WENN(B2>10000;B2*0,05;""). Die Zelle sieht leer aus, enthält aber einen leeren Text, deshalb ergibt ISTLEER für sie FALSCH.

Wie viele WENN kann ich ineinander verschachteln?

Excel erlaubt 64, aber nach drei oder vier wird die Formel schwer lesbar. Nimm lieber WENNS oder eine Nachschlagetabelle mit SVERWEIS oder XVERWEIS.

Wie heißt WENN auf Englisch?

IF. Im englischen Excel schreibst du IF statt WENN. In den Übungen hier kannst du beide Namen verwenden.

Verwandte Funktionen